定义 ExUnit 回调。

此模块定义了 setup/1、setup/2、setup_all/1 和 setup_all/2 回调，以及 on_exit/2、start_supervised/2 和 stop_supervised/1 函数。

设置回调可用于定义 测试夹具 并运行任何初始化代码，这些代码有助于将系统置于已知状态。它们通过宏定义，每个宏可以选择接收包含测试状态和元数据的映射，通常称为 context。可选地，通过返回适当结构的值（见下文），设置回调可以扩展测试中使用的上下文。

setup_all 回调在每个模块中只调用一次，在运行任何测试之前。所有 setup 回调在每次测试之前运行。如果测试用例没有测试或所有测试都被过滤掉，则不会运行任何回调。

setup 和 setup_all 回调可以通过代码块、命名本地函数的原子、{module, function} 元组或原子/元组列表来定义。

两者都可以选择通过将当前上下文指定为参数来接收当前上下文（如果通过代码块定义）。用于定义测试设置的函数必须接受上下文作为单个参数。

测试模块可以定义多个 setup 和 setup_all 回调，它们按出现顺序调用。

start_supervised/2 用于在主管进程下启动进程。主管进程与当前测试进程链接。主管进程以及所有子进程都保证在任何 on_exit/2 回调运行之前终止。

on_exit/2 回调按需注册，通常用于撤消设置回调执行的操作。 on_exit/2 也可以接受引用，允许在将来覆盖回调。已注册的 on_exit/2 回调将始终运行，而 setup 和 setup_all 中的错误将阻止所有剩余的设置回调执行。

最后， setup_all 回调在每个模块中运行在一个单独的进程中，而所有 setup 回调在与测试本身相同的进程中运行。 on_exit/2 回调始终在单独的进程中运行，正如其名称所暗示的那样。测试进程始终以原因 :shutdown 退出，这意味着与测试进程链接的任何进程也将退出，尽管是异步的。因此，最好使用 start_supervised/2 来保证同步终止。

以下是测试进程的生命周期概述

1. 测试进程被生成
2. 它运行 setup/2 回调
3. 它运行测试本身
4. 它停止所有受监督的进程
5. 测试进程以原因 :shutdown 退出
6. on_exit/2 回调在单独的进程中执行

上下文

如果 setup_all 或 setup 返回关键字列表、映射或形状为 {:ok, keyword() | map()} 的元组，则关键字列表或映射将合并到当前上下文，并将可用于所有后续 setup_all、setup 和 test 本身。

返回 :ok 会使上下文保持不变（在 setup 和 setup_all 回调中）。

从 setup_all 返回任何其他内容将强制所有测试失败，而从 setup 返回错误响应将导致当前测试失败。

示例

defmodule AssertionTest do
  use ExUnit.Case, async: true

  # "setup_all" is called once per module before any test runs
  setup_all do
    IO.puts("Starting AssertionTest")

    # Context is not updated here
    :ok
  end

  # "setup" is called before each test
  setup do
    IO.puts("This is a setup callback for #{inspect(self())}")

    on_exit(fn ->
      IO.puts("This is invoked once the test is done. Process: #{inspect(self())}")
    end)

    # Returns extra metadata to be merged into context.
    # Any of the following would also work:
    #
    #     {:ok, %{hello: "world"}}
    #     {:ok, [hello: "world"]}
    #     %{hello: "world"}
    #
    [hello: "world"]
  end

  # Same as above, but receives the context as argument
  setup context do
    IO.puts("Setting up: #{context.test}")

    # We can simply return :ok when we don't want to add any extra metadata
    :ok
  end

  # Setups can also invoke a local or imported function that returns a context
  setup :invoke_local_or_imported_function

  test "always pass" do
    assert true
  end

  test "uses metadata from setup", context do
    assert context[:hello] == "world"
    assert context[:from_named_setup] == true
  end

  defp invoke_local_or_imported_function(context) do
    [from_named_setup: true]
  end
end

将您的设置定义为一系列函数也很常见，这些函数通过调用 setup 或 setup_all 并传递函数名列表来组合在一起。这些函数中的每一个都接收上下文并可以返回 setup 代码块中允许的任何值

defmodule ExampleContextTest do
  use ExUnit.Case

  setup [:step1, :step2, :step3, {OtherModule, :step4}]

  defp step1(_context), do: [step_one: true]
  defp step2(_context), do: {:ok, step_two: true} # return values with shape of {:ok, keyword() | map()} allowed
  defp step3(_context), do: :ok # Context not modified

  test "context was modified", context do
    assert context[:step_one] == true
    assert context[:step_two] == true
  end
end

最后，正如 ExUnit.Case 文档中所述，请记住，初始上下文元数据也可以通过 @tag 设置，然后可以在 setup 代码块中访问

defmodule ExampleTagModificationTest do
  use ExUnit.Case

  setup %{login_as: username} do
    {:ok, current_user: username}
  end

  @tag login_as: "max"
  test "tags modify context", context do
    assert context[:login_as] == "max"
    assert context[:current_user] == "max"
  end
end